Deploy on Celestium

Deploying a Smart Contract on Celestium Testnet Using Remix

This guide will walk you through deploying an ERC-20 token smart contract on the Celestium Testnet using Remix , a web-based Solidity IDE.

Prerequisites

Before proceeding, ensure you have the following:

• A MetaMask wallet connected to the Celestium Testnet.

• Some test CLT tokens from the Celestium Faucet.

• Basic familiarity with Solidity and Remix IDE.

Step 1: Connect MetaMask to Celestium Testnet

1. Open MetaMask and go to Settings > Networks > Add Network.

2. Enter the Celestium Testnet details:

   • Network Name: Celestium Testnet

   • RPC URL: https://rpc-testnet.celestium.network

   • Chain ID: 252525

   • Currency Symbol: tCLT

   • Block Explorer URL: https://explorer-testnet.celestium.network

3. Click Save and switch to the Celestium Testnet network.

Step 2: Get Test CLT Tokens

1. Visit the Celestium Faucet.

2. Enter your MetaMask wallet address and request test CLT.

3. Wait for the tokens to be sent to your wallet.

Step 3: Open Remix and Load the Contract

1. Go to Remix IDE.

2. Click Create New File and name it Token.sol.

3. Copy and paste the following Solidity code:

// SPDX-License-Identifier: MIT

pragma solidity 0.8.16;

interface IERC20 {
    function totalSupply() external view returns (uint256);
    function balanceOf(address account) external view returns (uint256);
    function transfer(address recipient, uint256 amount) external returns (bool);
    function allowance(address owner, address spender) external view returns (uint256);
    function approve(address spender, uint256 amount) external returns (bool);
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);
   
    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

interface IERC20Metadata is IERC20 {
    function name() external view returns (string memory);
    function symbol() external view returns (string memory);
    function decimals() external view returns (uint8);
}

abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    function name() public view virtual override returns (string memory) {
        return _name;
    }

    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) public virtual override returns (bool) {
        uint256 currentAllowance = _allowances[sender][_msgSender()];
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "CLT20: transfer amount exceeds allowance");
            unchecked {
                _approve(sender, _msgSender(), currentAllowance - amount);
            }
        }

        _transfer(sender, recipient, amount);

        return true;
    }

    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender] + addedValue);
        return true;
    }

    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        uint256 currentAllowance = _allowances[_msgSender()][spender];
        require(currentAllowance >= subtractedValue, "CLT20: decreased allowance below zero");
        unchecked {
            _approve(_msgSender(), spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    function _transfer(
        address sender,
        address recipient,
        uint256 amount
    ) internal virtual {
        require(sender != address(0), "CLT20: transfer from the zero address");
        require(recipient != address(0), "CLT20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        uint256 senderBalance = _balances[sender];
        require(senderBalance >= amount, "CLT20: transfer amount exceeds balance");
        unchecked {
            _balances[sender] = senderBalance - amount;
        }
        _balances[recipient] += amount;

        emit Transfer(sender, recipient, amount);

        _afterTokenTransfer(sender, recipient, amount);
    }

    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "CLT20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        _balances[account] += amount;
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "CLT20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "CLT20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
        }
        _totalSupply -= amount;

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "CLT20: approve from the zero address");
        require(spender != address(0), "CLT20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

contract NameContract is ERC20 { // dont use space for this section
    constructor () ERC20("Name Coin", "TICKER/SYMBOL") // Change your name Coin and Ticker
    {    
        _mint(msg.sender, 100_000_000 * (10 ** 18)); // Supply of Coin & Decimals
    }
}

• Replace "Name Coin" with your token name.

• Replace "TICKER" with your token symbol.

Step 4: Compile the Smart Contract

1. In Remix, go to the Solidity Compiler tab.

2. Select the Solidity Version 0.8.16.

3. Click Compile Token.sol.

4. Ensure there are no errors before proceeding.

Step 5: Deploy on Celestium Testnet

1. Go to the Deploy & Run Transactions tab.

2. In the Environment dropdown, select Injected Provider - MetaMask.

3. Make sure your MetaMask is connected to Celestium Testnet.

4. Click Deploy and confirm the transaction in MetaMask.

Step 6: Verify Deployment

1. Copy the contract address from Remix.

2. Visit Celestium Testnet Explorer.

3. Paste the contract address in the search bar to view details.

Step 7: Interact with Your Token

1. Add your token to MetaMask:

   • Open MetaMask and click Import Tokens.

   • Enter the contract address.

   • Click Add Token.

2. Test token transfers:

   • Use Remix to call transfer() to send tokens.

   • Check the balance using balanceOf().

Conclusion

You have successfully deployed an ERC-20 token on the Celestium Testnet using Remix. This token can now be used for further development, testing, or integration with dApps.

For additional support, join the Celestium Community:

🔹 Telegram: @Celestium_Network 🔹 Website: Celestium.network 🔹 Faucet: Get Test CLT